cmake_minimum_required (VERSION 2.8.6)
PROJECT (HDFJAVAExamples_NATIVE_H5 Java)

SET(CMAKE_VERBOSE_MAKEFILE 1)

INCLUDE_DIRECTORIES(
    ${HDFJAVA_LIB_DIR}
)

SET (HDF_JAVA_EXAMPLES
    HDF5FileCreate
    HDF5GroupCreate
    HDF5DatasetCreate
    HDF5AttributeCreate
    HDF5DatasetRead
    HDF5FileStructure
    HDF5SubsetSelect
)

IF (WIN32 AND NOT CYGWIN)
  SET(CMAKE_JAVA_INCLUDE_FLAG_SEP ";")
ELSE (WIN32 AND NOT CYGWIN)
  SET(CMAKE_JAVA_INCLUDE_FLAG_SEP ":")
ENDIF(WIN32 AND NOT CYGWIN)

SET (CMAKE_JAVA_CLASSPATH ".")
FOREACH (CMAKE_INCLUDE_PATH ${CMAKE_JAVA_INCLUDE_PATH})
  SET(CMAKE_JAVA_CLASSPATH "${CMAKE_JAVA_CLASSPATH}${CMAKE_JAVA_INCLUDE_FLAG_SEP}${CMAKE_INCLUDE_PATH}")
ENDFOREACH(CMAKE_INCLUDE_PATH)

FOREACH (HCP_JAR ${CMAKE_JAVA_INCLUDE_PATH})
  GET_FILENAME_COMPONENT (_HCP_FILE ${HCP_JAR} NAME)
  SET (HDFJAVA_CLASSJARS "${_HCP_FILE} ${HDFJAVA_CLASSJARS}")
ENDFOREACH (HCP_JAR ${CMAKE_JAVA_INCLUDE_PATH})

FOREACH (example ${HDF_JAVA_EXAMPLES})
  FILE (WRITE ${PROJECT_BINARY_DIR}/Manifest.txt
  "Main-Class: jnative.h5.${example}
Class-Path: ${HDFJAVA_CLASSJARS}
"
  )
  ADD_JAR (${example} ${PROJECT_BINARY_DIR}/Manifest.txt ${example}.java)
  GET_TARGET_PROPERTY(${example}_JAR_FILE ${example} JAR_FILE)
ENDFOREACH (example ${HDF_JAVA_EXAMPLES})

IF (BUILD_TESTING)

  MACRO (ADD_H5_TEST resultfile resultcode)
    ADD_TEST (
        NAME jnative-h5-${resultfile}
        COMMAND "${CMAKE_COMMAND}"
            -D "TEST_TESTER=${CMAKE_Java_RUNTIME}"
            -D "TEST_PROGRAM=jnative.h5.${resultfile}"
            -D "TEST_ARGS:STRING=${ARGN}"
            -D "TEST_CLASSPATH:STRING=${CMAKE_JAVA_CLASSPATH}${CMAKE_JAVA_INCLUDE_FLAG_SEP}${${resultfile}_JAR_FILE}"
            -D "TEST_LIBRARY_DIRECTORY=${HDFJAVA_LIBRARIES}"
            -D "TEST_FOLDER=${HDFJAVAExamples_NATIVE_BINARY_DIR}"
            -D "TEST_OUTPUT=${HDFJAVAExamples_NATIVE_H5_BINARY_DIR}/${resultfile}.out"
            -D "TEST_EXPECT=${resultcode}"
            -D "TEST_SKIP_COMPARE=TRUE"
            -P "${HDFJAVA_RESOURCES_DIR}/runTest.cmake"
    )
    IF (NOT "${last_test}" STREQUAL "")
      SET_TESTS_PROPERTIES (jnative-h5-${resultfile} PROPERTIES DEPENDS ${last_test})
    ENDIF (NOT "${last_test}" STREQUAL "")
    SET (last_test "jnative-h5-${resultfile}")
  ENDMACRO (ADD_H5_TEST file)

  FOREACH (example ${HDF_JAVA_EXAMPLES})
    ADD_TEST (
        NAME jnative-h5-${example}-clearall-objects
        COMMAND    ${CMAKE_COMMAND}
            -E remove
            ${HDFJAVAExamples_NATIVE_BINARY_DIR}/${example}.h5
            ${example}.out
            ${example}.out.err
    )
    IF (NOT "${last_test}" STREQUAL "")
      SET_TESTS_PROPERTIES (jnative-h5-${example}-clearall-objects PROPERTIES DEPENDS ${last_test})
    ENDIF (NOT "${last_test}" STREQUAL "")
    ADD_H5_TEST (${example} 0)
  ENDFOREACH (example ${HDF_JAVA_EXAMPLES})

ENDIF (BUILD_TESTING)