cmake_minimum_required (VERSION 3.2.2)
PROJECT (HDFJAVA_JNI_HDFLIB C)

set (HDFJAVA_JNI_HDF_CSRCS
    ${HDFJAVA_JNI_HDFLIB_SOURCE_DIR}/hdfanImp.c
    ${HDFJAVA_JNI_HDFLIB_SOURCE_DIR}/hdfdfanImp.c
    ${HDFJAVA_JNI_HDFLIB_SOURCE_DIR}/hdfdfcompImp.c
    ${HDFJAVA_JNI_HDFLIB_SOURCE_DIR}/hdfdfpalImp.c
    ${HDFJAVA_JNI_HDFLIB_SOURCE_DIR}/hdfdfsdImp.c
    ${HDFJAVA_JNI_HDFLIB_SOURCE_DIR}/hdfdfuImp.c
    ${HDFJAVA_JNI_HDFLIB_SOURCE_DIR}/hdfexceptionImp.c
    ${HDFJAVA_JNI_HDFLIB_SOURCE_DIR}/hdfgrImp.c
    ${HDFJAVA_JNI_HDFLIB_SOURCE_DIR}/hdfheImp.c
    ${HDFJAVA_JNI_HDFLIB_SOURCE_DIR}/hdfhxImp.c
    ${HDFJAVA_JNI_HDFLIB_SOURCE_DIR}/hdfImp.c
    ${HDFJAVA_JNI_HDFLIB_SOURCE_DIR}/hdfnativeImp.c
    ${HDFJAVA_JNI_HDFLIB_SOURCE_DIR}/hdfr24Imp.c
    ${HDFJAVA_JNI_HDFLIB_SOURCE_DIR}/hdfr8Imp.c
    ${HDFJAVA_JNI_HDFLIB_SOURCE_DIR}/hdfsdsImp.c
    ${HDFJAVA_JNI_HDFLIB_SOURCE_DIR}/hdfstructsutil.c
    ${HDFJAVA_JNI_HDFLIB_SOURCE_DIR}/hdfvdataImp.c
    ${HDFJAVA_JNI_HDFLIB_SOURCE_DIR}/hdfvfImp.c
    ${HDFJAVA_JNI_HDFLIB_SOURCE_DIR}/hdfvgroupImp.c
    ${HDFJAVA_JNI_HDFLIB_SOURCE_DIR}/hdfvhImp.c
    ${HDFJAVA_JNI_HDFLIB_SOURCE_DIR}/hdfvqImp.c
    ${HDFJAVA_JNI_HDFLIB_SOURCE_DIR}/hdfvsqImp.c
)

INCLUDE_DIRECTORIES ( ${HDFJAVA_JNI_HDFLIB_SOURCE_DIR} )

set (CMAKE_INCLUDE_CURRENT_DIR_IN_INTERFACE ON)

########### JNI libraries always must be built shared  ###############
add_library (${HDFJAVA_JNI_HDF_LIB_TARGET} SHARED ${HDFJAVA_JNI_HDF_CSRCS})
TARGET_C_PROPERTIES (${HDFJAVA_JNI_HDF_LIB_TARGET} SHARED " " " ")
if (WIN32)
  TARGET_LINK_LIBRARIES (${HDFJAVA_JNI_HDF_LIB_TARGET} ${HDF4_LINK_LIBS} "ws2_32.lib")
else ()
  TARGET_LINK_LIBRARIES (${HDFJAVA_JNI_HDF_LIB_TARGET} ${HDF4_LINK_LIBS})
endif ()
SET_GLOBAL_VARIABLE (HDFJAVA_LIBRARIES_TO_EXPORT "${HDFJAVA_LIBRARIES_TO_EXPORT};${HDFJAVA_JNI_HDF_LIB_TARGET}")
HDFJAVA_SET_LIB_OPTIONS (${HDFJAVA_JNI_HDF_LIB_TARGET} ${HDFJAVA_JNI_HDF_LIB_NAME} SHARED)
if (WIN32)
  get_filename_component (HDFJAVA_JNI_HDF_DLL_NAME ${HDFJAVA_JNI_HDF_LIB_TARGET} NAME_WE)
  # message (STATUS "HDFJAVA_JNI_HDF_DLL_NAME: ${HDFJAVA_JNI_HDF_DLL_NAME}")
  if (BUILD_TESTING)
    add_custom_target (HDFJAVA_JNI_HDF-Test-Copy ALL
        COMMAND ${CMAKE_COMMAND} -E copy_if_different ${CMAKE_RUNTIME_OUTPUT_DIRECTORY}/${CMAKE_CFG_INTDIR}/${HDFJAVA_JNI_HDF_DLL_NAME}${CMAKE_SHARED_LIBRARY_SUFFIX} ${CMAKE_RUNTIME_OUTPUT_DIRECTORY}/${HDFJAVA_JNI_HDF_DLL_NAME}${CMAKE_SHARED_LIBRARY_SUFFIX}
        COMMENT "Copying ${CMAKE_RUNTIME_OUTPUT_DIRECTORY}/${CMAKE_CFG_INTDIR}/${HDFJAVA_JNI_HDF_DLL_NAME}${CMAKE_SHARED_LIBRARY_SUFFIX} to ${CMAKE_RUNTIME_OUTPUT_DIRECTORY}/"
    )
    add_dependencies (HDFJAVA_JNI_HDF-Test-Copy ${HDFJAVA_JNI_HDF_LIB_TARGET})
  endif ()
endif ()

#-----------------------------------------------------------------------------
# Add Target(s) to CMake Install for import into other projects
#-----------------------------------------------------------------------------
if (HDFJAVA_EXPORTED_TARGETS)
  install (
      TARGETS
          ${HDFJAVA_JNI_HDF_LIB_TARGET}
      EXPORT
          ${HDFJAVA_EXPORTED_TARGETS}
      LIBRARY DESTINATION ${HJAVA_INSTALL_LIB_DIR} COMPONENT libraries
      ARCHIVE DESTINATION ${HJAVA_INSTALL_LIB_DIR} COMPONENT libraries
      RUNTIME DESTINATION ${HJAVA_INSTALL_LIB_DIR} COMPONENT libraries
      FRAMEWORK DESTINATION ${HJAVA_INSTALL_FWRK_DIR} COMPONENT libraries
      INCLUDES DESTINATION include
  )
endif ()